pro get_sdl_info, index, data, avg, dev, exp_avg=exp_avg
;
;+
;NAME:
;	get_sdl_avg
;PURPOSE:
;	To take the data structure from the SDL data files and return
;	the average and standard deviation for each image
;CALLING SEQUENCE:
;	get_sdl_info, index, data, avg, dev
;INPUT:
;	index
;	data
;OUTPUT:
;	avg
;	dev
;OPTIONAL KEYWORD OUTPUT:
;	exp_avg	- the EXPECTED average DN level based on exposure duration
;		  and a linear fit
;HISTORY:
;	Written 20-Apr-92 by M.Morrison
;	 2-Feb-93 (MDM) - Modified to pass BYTE type to SXT_DECOMP
;-
;
n = n_elements(index)
avg = fltarr(n)
dev = fltarr(n)
exp_avg = fltarr(n)
;
vals = sxt_decomp(byte(indgen(256)))
for i=0,n-1 do begin
	npix = total(data(i).hist)
	v = data(i).hist * vals
	avg0 = total(v)/npix
	tmp = (vals-avg0)
	tmp = tmp^2*data(i).hist
	dev0 = sqrt( total(tmp) / (npix-1) )
	avg(i) = avg0
	dev(i) = dev0
	;
	res = gt_res(index(i))
	expdur = gt_dpe(index(i), /conv)/1000.	;expected exposure duration
	case gt_res(index(i)) of
	    0: exp_avg(i) = 13.5  + 0.13 *expdur		;guessing based on calibration data from pre-launch and increases
	    1: exp_avg(i) = 29.88 + 0.574*expdur		;From fit made 16-Apr-92
	    2: exp_avg(i) = 67.68 + 1.999*expdur		;From fit made 16-Apr-92
	end
end

end