function gt_comp, item, string=string, short=short, header=header, spaces=spaces
;
;+
;NAME:
;	gt_comp
;PURPOSE:
;	To extract the bits corresponding to image compression and optionally
;	return the string nemonic for that compression
;CALLING SEQUENCE:
;	print, gt_comp()		;print full listing of compressions
;	comp = gt_comp(index)
;METHOD:
;	The input can be a structure or a scalar.  The structure can
;	be the index, or roadmap, or observing log.  If the input
;	is non-byte type, it assumes that the bit extraction had
;	already occurred and the "mask" is not performed on the input.
;INPUT:
;	item	- A structure or scalar.  It can be an array.  If this
;		  value is not present, a help summary is printed on the
;		  filter names used.
;OPTIONAL INPUT:
;	string	- If present, return the string mnemonic (long notation)
;	short	- If present, return the short string nemonic 
;	spaces	- If present, place that many spaces before the output
;                 string.
;OUTPUT:
;	returns	- The compression selected, a integer value or a string
;		  value depending on the switches used.  It is a vector
;		  if the input is a vector
;OPTIONAL OUTPUT:
;	header	- A string that describes the item that was selected
;		  to be used in listing headers.
;HISTORY:
;	Written 7-Nov-91 by M.Morrison
;	13-Nov-91 MDM - Added "header" and "spaces" option
;	15-Nov-91 MDM - Changed short notation from 1x1, 2x2, 4x4 to
;			FR, HR, QR
;-
;
head_long = 'Comp'
head_short = 'C'
conv2str = ['Comp', 'Low8', 'Hi8 ', '????']	;4 characters
conv2short = ['C', 'L', 'H', '?']		;1 characters
;
if (n_params(0) eq 0) then begin
    print, 'String Output for GET_COMP'
    for i=0,2 do print, i, conv2str(i), conv2short(i), format='(i3, 2x, a6, 2x, a6)'
    return, ''
end
;
siz = size(item)
typ = siz( siz(0)+1 )
if (typ eq 8) then begin
    ;Check to see if an index was passed (which has the "periph" tag
    ;nested under "sxt", or a roadmap or observing log entry was
    ;passed
    tags = tag_names(item)
    if (tags(0) eq 'GEN') then out = item.sxt.imgparam $
			else out = item.imgparam
end else begin
    out = item
end
;
;---- If the item passed is byte type, then assume that it is a
;     raw telemetered value and the item's bits need to be extracted
siz = size(out)
typ = siz( siz(0)+1 )
if (typ eq 1) then out = mask(out, 2, 2)	;if it is byte type - then mask
out = out>0<3	;check range
;
out = gt_conv2str(out, conv2str, conv2short, header_array, header=header, $
        string=string, short=short, spaces=spaces)

;
return, out
end