pro help_vignette, hc=hc, eps=eps, file=file
;+
; NAME:
;   help_vignette
; PURPOSE:
;   To display the SXT Vignette function
; CALLING SEQUENCE:
;   help_vignette
;   help_vignette,/hc
;   help_vignette,/hc,file=file
; OPTIONAL KEYWORD INPUT:
;   hc	   = If set, make a hardcopy of the plot
;   file   = To specify output PostScript file name
;   eps	   = If set, make an encapsulated PostScript file
; RESTRICTIONS:
; MODIFICATION HISTORY:
; 13-jan-93, J. R. Lemen LPARL, Written (calls sxt_vignette)
;-

if (keyword_set(hc) or (!d.name eq 'PS')) then begin
    set_plot, 'ps'
    xsize = 5.5			; Plot size in inches
    ysize = 3.5
    device, xsize=xsize , ysize=ysize , /inches
    if (keyword_set(eps)) then device, /encapsulated
    charsize=1.
    if (keyword_set(file)) then begin & device, /close & device, file=file(0) & end
endif else charsize = 1.5

; Get the optical axis location
x = (gt_sxt_axis())(0)		; = 515
y = (gt_sxt_axis())(1)		; = 633

npts = 725	; Chosen so X-axis range will be 0 to 30 arc-min
ang = indgen(Npts) * gt_pix_size() / 60		; Angle in arc-min


plot,ang,sxt_vignette([x,y,Npts,1,0],/qtest),		$	; Low-energy
	charsize=charsize,				$
	xtitle='Off Axis Angle (arc-min)',		$
	ytitle='Relative Intensity', 			$
	title ='Effective Area of SXT vs Off Axis Angle'
oplot,ang,sxt_vignette([x,y,Npts,1,0],2,/qtest),line=1		; High energy
xyouts,/data,total(!x.crange)/2.,.1,align=.5,		$
	charsize=charsize,				$
	string('Rel Int=1.0 is at CCDx =',x,', CCDy =',y,format='(a,i4,a,i4)')
xyouts,/data,20,.45,'High-energy',align=1.,charsize=charsize
xyouts,/data,22,.8,'Low-energy',align=0.,charsize=charsize

empty
if !d.name eq 'PS' then device,/close
if keyword_set(hc) then pprint,/reset

set_plot,'x'
end