function deka_norm, index, data, dekaindex=dekaindex
;+
;NAME:
;        deka_norm
;PURPOSE:
;	Create time-series images normalized to an exposure of 100 seconds.
;CATEGORY:
;        Yohkoh/SXT analysis 
;CALLING SEQUENCE:
;	img = deka_norm(index, data)
;INPUT:
;	index	- index structure
;	data	- data cube (if byte type will be sxt_decompressed)
;OPTIONAL INPUT:
;	none
;OPTIONAL KEYWORD INPUT:
;	none
;OUTPUT:
;	returns	- normalized data (floating point data type) in 
;		  DN/dekasec
;OPTIONAL KEYWORD OUTPUT:
;	dekaindex = index structure with modified exposure in history
;MODIFICATION HISTORY:
;	10/20/96 [LWA]  Prepared from exp_norm.pro
;-
;

expdur = gt_expdur(index)
siz = size(data)
if (siz(0) eq 3) then n = siz(3) else n=1
typ = siz( siz(0) + 1)
;
if (typ eq 1) then out = float(sxt_decomp(data)) else out = float(data)
 for i=0, n-1 do begin
    out(0, 0, i) = 1e5 * out(*,*,i) / expdur(i)
 endfor
;
dekaindex=index
his_index, dekaindex, -1, 'expdur', 100000.   ;normalized to 100 sec = 100000 msec
;
return, out
end