function mk_daily_ints,sttim,entim

;+
; NAME
;	mk_daily_ints
; PURPOSE
;	To create a one-per-day time structure.
; CALLING SEQUENCE
;	tout = mk_daily_ints('15-sep-91','11-nov-95')
; INPUT
;	sttim, entim - first and last days in any format.
; OUTPUT
;	Yohkoh time structure for the time interval.
; PROCEDURES CALLED
;	anytim2ex, anytim2doy, leap_yr, anytim2ints, str_concat
; HISTORY
;	17-Jan-96, LWA, written.
;-

t1=anytim2ex(sttim)
t2=anytim2ex(entim)
d1=anytim2doy(sttim)
d2=anytim2doy(entim)
yy=t2(6)-t1(6)

; Deal with the first year.
if yy eq 0 then begin
   lyr=leap_yr(t1(6))
   if lyr eq 1 then tz=indgen(366)+1 else tz=indgen(365)+1
   daze=indgen(d2-(d1-1))+d1-1
   tday=anytim2ints(doy2ex(tz(daze),t1(6)))
endif else begin
   lyr=leap_yr(t1(6))
   if lyr eq 1 then tz=indgen(366)+1 else tz=indgen(365)+1
   daze=indgen(max(tz)-(d1-1))+d1-1
   tday=anytim2ints(doy2ex(tz(daze),t1(6)))
endelse

; Deal with intermediate years.
if yy gt 1 then begin
   for j=1,yy-1 do begin
      lyr=leap_yr(t1(6)+j)
      if lyr eq 1 then tz=indgen(366)+1 else tz=indgen(365)+1
      tday2=anytim2ints(doy2ex(tz,t1(6)+j))
      tday=str_concat(tday,temporary(tday2))
   endfor
endif

; Deal with the last year -- unless there is only one year.
if yy gt 0 then begin
   lyr=leap_yr(t2(6))
   if lyr eq 1 then tz=indgen(366)+1 else tz=indgen(365)+1
   daze=indgen(d2)
   tday2=anytim2ints(doy2ex(tz(daze),t2(6)))
   tday=str_concat(tday,temporary(tday2))
endif

return, tday

end