pro plott_hda, input1, input2, psym=psym
;
;+
;NAME:
;	plott_hda
;PURPOSE:
;	Plot light curve for HXT data.
;CALLING SEQUENCE:
;	plott_hda, input1, input2
;	plott_hda, roadmap
;	plott_hda, index, psym=0
;	plott_hda, '15-nov-91 20:00', 60
;INPUT:
;	A single parameter call is used to pass ROADMAP, INDEX or
;	OBSERVING LOG in.  Two parameters can be used to specify the
;	date/time and duration or end time.
;
;	input1	- A structure array (roadmap, index or obs log)
;			or
;		  The start time to plot from
;	input2	- If the value is a scalar, it is the duration in
;		  minutes to plot.  The other option is to specify the
;		  end date/time.
;OPTIONAL KEYWORD INPUT:
;	psym	- The plotting symbol to use.  Default is 3 (+)
;HISTORY:
;	Written 7-Mar-92 by M.Morrison
;	20-Dec-93 (MDM) - Modified to accept times in addition to an HXT
;			  structure (index/roadmap)
;-
;
if (n_elements(psym) eq 0) then psym = 3
if (n_params(0) eq 2) then begin
    sttim = input1
    if (data_type(input2) le 5) then entim = anytim2ints(sttim, off=input2*60) $
				else entim = input2
    rd_obs, sttim, entim, bcs, sxtf, sxtp, input, /w_h
    if (get_nbytes(input(0)) lt 10) then begin
	message, 'No HXT data available for that time period', /info
	return
    end
end else begin
    input = input1
end
;
!p.multi = [0,1,4]
!p.charsize = 1.3
;
utplot, input, psym=psym, /ynozer, gt_sum_l(input, tit=tit),  title = tit, ytitle = 'Counts/sec'
utplot, input, psym=psym, /ynozer, gt_sum_m1(input, tit=tit),  title = tit, ytitle = 'Counts/sec'
utplot, input, psym=psym, /ynozer, gt_sum_m2(input, tit=tit),  title = tit, ytitle = 'Counts/sec'
utplot, input, psym=psym, /ynozer, gt_sum_h(input, tit=tit),  title = tit, ytitle = 'Counts/sec'
;
!p.multi = 0
end